ReferencePlatforms/Test/Win7

No full reference exists, but Alice says she followed the Vista instructions when creating this ref machine.

Setup

• disable sound

MozillaBuild 1.4

• In bug 549458 we installed MozillaBuild 1.4
• Checkout 'mozilla-build-1.4.zip' and 'python25win32dlls.zip' from the mofo repo. Read this comment to know where they are located.

unzip mozilla-build-1.4.zip -d C:\
unzip python25win32dlls.zip -d C:\mozilla-build\python25\Scripts
rm mozilla-build-1.4.zip
rm python25win32dlls.zip

buildbot

Install Buildbot

Install Buildbot using the following batch script. You will need to find a way to get this batch script onto the system. This installs buildbot into %mozillabuild%\buildbotve, using the version in the SET at the top. It gets Python packages from the puppet master specified in pkg_root. Note that runas /administrator doesn't work in W7, so you'll need to use VNC to install runslave.py (below)

@echo off
SET version=0.8.4-pre-moz2

REM find mozillabuild
SET mozillabuild=d:\mozilla-build
SET mozilladrive=d:
IF NOT EXIST %mozillabuild%\nul (
    SET mozillabuild=c:\mozilla-build
    SET mozilladrive=c:
)

REM find python - some machines have python26, some have python25
SET pythondir=%mozillabuild%\python25\
SET pythondll=python25.dll
IF NOT EXIST %pythondir%\python.exe (
    REM python26 isn't in a versioned directory for some reason
    SET pythondir=%mozillabuild%\python
    SET pythondll=python26.dll
)

SET python=%pythondir%\python.exe
SET pkg_root=http://production-puppet.build.mozilla.org/production/python-packages
SET virtualenv=%mozillabuild%\buildbotve

REM get set up
rmdir /s /q %virtualenv%
if ERRORLEVEL 1 exit /b 1
MKDIR %virtualenv%
if ERRORLEVEL 1 exit /b 1

%mozilladrive%
cd %virtualenv%


REM On systems where Python is not installed systemwide, the python.exe in the virtualenv
REM will not be able to find PYTHON*.DLL, so we copy it there "manually"
MKDIR %virtualenv%\scripts
if ERRORLEVEL 1 exit /b 1

COPY %pythondir%\%pythondll% %virtualenv%\scripts
if ERRORLEVEL 1 exit /b 1


REM get the prerequisites for a virtualenv
%mozillabuild%\wget\wget %pkg_root%/virtualenv.py
if ERRORLEVEL 1 exit /b 1

%mozillabuild%\wget\wget %pkg_root%/pip-0.8.2.tar.gz
if ERRORLEVEL 1 exit /b 1

%mozillabuild%\wget\wget %pkg_root%/distribute-0.6.14.tar.gz
if ERRORLEVEL 1 exit /b 1


REM create the virtualenv
%python% virtualenv.py --python=%python% --distribute %virtualenv%
if ERRORLEVEL 1 exit /b 1


REM populate it
.\scripts\pip install --no-deps --no-index --find-links=%pkg_root% zope.interface==3.6.1
if ERRORLEVEL 1 exit /b 1

.\scripts\pip install --no-deps --no-index --find-links=%pkg_root% buildbot-slave==%version%
if ERRORLEVEL 1 exit /b 1

.\scripts\pip install --no-deps --no-index --find-links=%pkg_root% buildbot==%version%
if ERRORLEVEL 1 exit /b 1

REM note that this version of Twisted has been modified to not require a
REM compiler; see the puppet manifests for details
.\scripts\pip install --no-deps --no-index --find-links=%pkg_root% twisted==10.2.0
if ERRORLEVEL 1 exit /b 1

.\scripts\pip install --no-deps --no-index --find-links=%pkg_root% simplejson==2.1.3
if ERRORLEVEL 1 exit /b 1

Deploy slave-alloc

• bug 629692 - slave-side slave-alloc support for w7/32
• Install runslave.py in C:\
  • You will need to do this with administrator privs. The only way to get these privs is to right-click "Command Prompt" on the start menu, and select "Run as Administrator". Then use 'wget' to download the file.

REM REMEMBER: "Run as Administrator"
wget -O c:\runslave.py http://hg.mozilla.org/build/puppet-manifests/raw-file/tip/modules/buildslave/files/runslave.py
dir C:\runslave.py

• Install startTalos.bat with:

 wget -O "c:\Users\cltbld\Desktop\startTalos2.bat" http://hg.mozilla.org/build/puppet-manifests/raw-file/default/modules/buildslave/files/startTalos-w7.bat

• set startTalos.bat to start on run
  • see https://bugzilla.mozilla.org/show_bug.cgi?id=430832#c1 although details are vague
  • In Task Manager, add a new task:
    • Run in C:\, run as cltbld, run only when logged in, run with highest priviledges
    • Triggers: at log on
    • Action: start c:\Users\cltbld\Desktop\startTalos.bat
    • Conditions: stop if idle ceases, start only on AC power, stop on switch to battery
    • Settings: Allow to run on demand, stop if running for more than 3 days, force stop if it does not stop when requested

ANGLE libraries

• In bug 589814 we deployed the ANGLE libraries into C:\libs (revision r411)

libEGL.dll
libGLESv2.dll

• You can download them from angle_libs.zip

Microsoft_VC80_DebugCRT_x86.msi

• We need to run debug builds on test machines which don't have Visual Studio installed
• This is explained in "Preparing a Test Machine To Run a Debug Executable"
• Follow these instructions to find out how to install it as an MSI file

md5sum -> ab9907210c0f95733cb8465b4dfa28d8  Microsoft_VC80_DebugCRT_x86.msi

DirectX runtime (June 2010)

See bug 624044

wget http://download.microsoft.com/download/1/7/1/1718CCC4-6315-4D8E-9543-8E28A4E18C4C/dxwebsetup.exe
dxwebsetup.exe

NVidia drivers update (Version: 260.99; Date: 2010.10.25)

See bug 624044

wget http://us.download.nvidia.com/Windows/260.99/260.99_desktop_win7_winvista_32bit_english_whql.exe
C:\Users\cltbld\Downloads\260.99_desktop_win7_winvista_32bit_english_whql.exe

Xperf

See bug 640829. NOTE: Followed instructions from Profiling with Xperf

To install this package unto your slave:

• Install the Windows 7 SDK
• Install C:\Program Files\Microsoft SDKs\Windows\v7.1\Redist\Windows\wpt_x86.msi